敵が自機に向けて弾を撃ちます。

　敵の弾は画面上に最大１００個まで存在できることにします。敵弾の存在フラグを配列変数eshotfで管理します。（eはenemyの略です。）敵弾のの座標値は、整数を入れる(eshotx,eshoty)と固定小数を入れる(smeshotx,smeshoty)の２通りを用意します。（smはsmall numberの略です。）例えば、敵弾のｘ座標が6.5の時、eshotxには6、smeshotxには1664（固定小数表現で6.5）を入れます。
　それと、１回にｘ方向、ｙ方向に何ドット動かすかを(smeshotdx,smeshotdy)で管理します。これは固定小数です。
    dim eshotf,100
    dim eshotx,100:dim eshoty,100
    dim smeshotx,100:dim smeshoty,100
    dim smeshotdx,100:dim smeshotdy,100
　この処理は、「プログラム起動時の初期設定」部分に入れることにします。

　各ステージが始まった時に、敵の弾がまだ１発も存在していない状態にします。
    repeat 100
        eshotf.cnt=0
    loop
　この処理は、「ステージスタート時の初期設定」部分に追加します。

　emsin,emcosを使います。
    emcos x,r
    emsin y,r
　それぞれ、角度rに対してコサイン値を求めてxに、サイン値を求めてyに代入します。角度は、０度以上３６０度未満の値を指定できれば十分ですね？　４５０度は９０度と同じですし、−９０度は２７０度と同じです。３６０度は０度と同じです。HSPEXT.DLLでは０度は0.0で、３６０度が1.0です。すると、0.0以上1.0未満の値、整数表現では０以上２５５以下の値を指定できれば十分ということになります。（emcos、emsinの角度にはこの範囲外の数値も指定できます。が、２５６は０と同じですし、−６４は１９２と同じです。）ということは、角度が２５６個の数値しかないのですから、サイン、コサイン値もそれぞれ２５６通りしかないということです。ならば、プログラムの最初の方で前もって計算し、配列変数に入れておき、それを利用するようにすれば、敵弾の射出を行うたびにサイン、コサイン計算をしなくてもすむことになります。
    dim vsin,256
    dim vcos,256
    repeat 256
        emcos x,cnt
        emsin y,cnt
        vcos.cnt=x
        vsin.cnt=y
    loop
　例えば角度が６４（固定小数表現では0.25、９０度）の時のサイン、コサイン値はvsin.64、vcos.64です。（vはvalueの略です。）
　少しでも処理速度を上げるために、このような事を行います。アークタンジェント(ematan)は、その都度計算するしかありませんが。
　この処理は「プログラム起動時の初期設定」に追加します。

　ここから敵弾の出現処理の話です。
　敵は、最大１０匹います。それぞれにつき、弾を撃つ処理を行います。毎回出していたら画面中が弾だらけになってしまいますから、敵が６４回移動する毎に１回にします。何回移動したかは、敵の移動処理で、enemycntに入れています。enemycntが６４の倍数の時にだけ撃つようにすれば、６４回に１回となります。
　存在する敵だけが弾を撃ちます。敵の出現位置（ｙ座標）は−３２、消滅位置はysizeですから、一瞬だけ画面外に存在します。画面の外側から弾を撃ってくるのは嫌ですから、敵が完全に画面内に現れている時だけとします。
    repeat 10
        if (enemyf.cnt=1)&(enemyx.cnt>=0)&(enemyx.cnt<=(xsize-32))
            &(enemyy.cnt>=0)&(enemyy.cnt<=(ysize-32))&(enemycnt.cnt\64=0) {
            n=cnt
            n番目の敵が弾を撃つ処理
        }
    loop
　見栄えのために、if文の途中に改行を入れましたが、実際には途中に改行を入れるとエラーになってしまいます。今は敵を１種類しか作っておらず、ｘ方向については画面の幅内におさまって動きますが、後々のことも考えてｘ座標についても制限しています。

　n番目の敵が弾を撃つ処理ですが、存在フラグを０番の要素から順に見ていき、空いている要素について必要な設定を行います。
    repeat 100
        if eshotf.cnt=0 {
            eshotf.cnt=1
            弾の座標を設定する。
            １回にｘ方向、ｙ方向のそれぞれに何ドット動かせばいいかを算出する。
            break
        }
    loop

　絵のファイル中の敵弾です。
　　
　弾は、敵の真ん中の位置に出すことにします。敵弾のサイズが８×８ドット、敵のサイズが３２×３２ドットですから、(enemyx.n+12,enemyy.n+12)です。
    eshotx.cnt=enemyx.n+12
    eshoty.cnt=enemyy.n+12
　これを固定小数に直します。
    smeshotx.cnt=eshotx.cnt<<8
    smeshoty.cnt=eshoty.cnt<<8

　弾を撃つ時に、自機のどこをねらえばいいかというと、自機がそのまま動かなかったとしたら自機の真ん中に行くようにねらうのがいいと思います。敵弾のサイズが８×８ドット、自機のサイズが３２×３２ドットですから、(playerx+12,playery+12)です。
　　
　弾の座標を中心とすると、飛び先の相対的な座標は(playerx+12-eshotx.cnt,playery+12-eshoty.cnt)となります。
　水色の矢印の角度rを求めます。
    ematan r,playerx+12-eshotx.cnt,playery+12-eshoty.cnt
    r=192-r
　第２引数にｘ成分、第３引数にｙ成分を指定すると、アークタンジェントを求めてrに代入します。２行目はematanとemsin,emcosの角度の定義が違うのを補正するためのものです。これを行うとrが０〜２５５の範囲に収まらなくなってしまいます。
　例えば４５０度は９０度に直す必要がありますし、４０５度は４５度に直す必要がありますし、−９０度は２７０度に直す必要があります。
　　角度=角度\360
　という計算を行うと、一見そうなりそうです。ところが、これは−９０度についてはうまくいきません。−９０を３６０で割った余りは２７０ではありません。−９０です。
　０が０度、２５６が３６０度に対応しますから、正の値だけを考えるならば、
　　角度=角度\256
　とすればいいです。しかし、もっといい方法があります。
　　角度=角度&255
　これですと、３２０（４５０度）は６４（９０度）に直りますし、２８８（４０５度)は３２（４５度）になりますし、−６４（−９０度）は１９２（２７０度）に直ります。mが２の何乗かである時だけ、"\m"を"&(m-1)"に変更できます。
　よって、２行目は
    r=(192-r)&255
　となります。

　水色の矢印上の、原点(0,0)から長さ１だけ離れた点の、ｘ座標はcos r、y座標はsin rです。なお、単位はドットです。ここでは１度に長さ６ドット分だけ動かすことにします。そのｘ成分、ｙ成分は以下のように求まります。
    smeshotdx.cnt=6*vcos.r
    smeshotdy.cnt=6*vsin.r

　以上より、敵の弾を射出する処理はこのようになります。
    repeat 10
        if (enemyf.cnt=1)&(enemyx.cnt>=0)&(enemyx.cnt<=(xsize-32))&
            (enemyy.cnt>=0)&(enemyy.cnt<=(ysize-32))&(enemycnt.cnt\64=0) {
            n=cnt
            repeat 100
                if eshotf.cnt=0 {
                    eshotf.cnt=1
                    eshotx.cnt=enemyx.n+12
                    eshoty.cnt=enemyy.n+12
                    smeshotx.cnt=eshotx.cnt<<8
                    smeshoty.cnt=eshoty.cnt<<8
                    ematan r,playerx+12-eshotx.cnt,playery+12-eshoty.cnt
                    r=(192-r)&255
                    smeshotdx.cnt=6*vcos.r
                    smeshotdy.cnt=6*vsin.r
                    break
                }
            loop
        }
    loop