アイテムを出し、それを取ったらオプションが追加される、あるいはボムが増えるようにします。

　マップ上のある地点に来たらアイテムを出します。アイテムは画面上部に現れ、スクロールと同じ速度でまっすぐ下りていき、下端に達すると消えます。自機がアイテムに当たると（アイテムを取ると）その種類に応じた効果（オプションが追加される、ボムが増える）が表れます。

「ゲームスタート時の初期設定」で、オプションの個数を０個にするように修正します。
    noption=0
　アイテムが出現しているかどうかを表す変数itemfを追加します。０は「存在しない」、１は「存在する」です。
「ステージスタート時の初期設定」で、０に設定します。
    itemf=0

　mappnt（現在位置）が１０２４、２０４８の時にオプション追加用アイテム、３０７２の時にボム追加用アイテムを出すことにします。４０９６でボスに到達するので、それぞれ１／４、２／４、３／４の地点です。
　変数itemx , itemyがアイテムの座標を表し、ikindがアイテムの種類を表すものとします。(item kindの略です。）０はオプション追加、１はボム追加とします。
　ｘ座標は画面の真ん中、ｙ座標は−３２に設定することにします。
    if (itemf=0)&((mappnt=1024)|(mappnt=2048)|(mappnt=3072)) {
        itemf=1
        if (mappnt=1024)|(mappnt=2048) { ikind=0 }
        if mappnt=3072 { ikind=1 }
        itemx=(xsize-32)/2
        itemy=-32
    }
　アイテムの大きさは３２×３２ドットです。するとｘ座標は真ん中なので、(xsize-32)/2となります。

　アイテムが存在したら、移動させます。ｙ座標に２足します。画面下端に達したら消します。
    if itemf=1 {
        itemy=itemy+2
        if itemy>=ysize { itemf=0 }
    }

　自機とアイテムの当たり判定は、自機が「通常」または「復活中」で、アイテムが「存在する」時に行います。「自機と敵、敵弾の当たり判定」では、自機の真ん中２×２ドットにしか当たり判定がないこととしましたが、アイテムは取りやすい（当たりやすい）方がいいので、３２×３２ドットで当たり判定を行います。
　当たっていたら、まずそのアイテムを消します。次に、その種類がオプション追加の場合はオプションの数noptionを１つ増やし、ボム追加の場合はボムの数nbombを１つ増やします。
　ただし、オプションは２個までしか増やしません。２個ある状態でオプション追加用アイテムを取ったら、スコアが５００点増えることとします。
    if ((playerf=1)|(playerf=2))&(itemf=1)&(playerx<=(itemx+31))
        &((playerx+31)>=itemx)&(playery<=(itemy+31))&((playery+31)>=itemy) {
        itemf=0
        if ikind=0 {
            if noption<2 {
                noption=noption+1
            }
            else {
                score=score+500
                if score>hiscore { hiscore=score }
                if score>=oneup {
                    nplayer=nplayer+1
                    oneup=oneup+100000
                }
            }
        }
        else {
            nbomb=nbomb+1
        }
    }

　絵のファイル中の、オプション追加用アイテム（Ｏ）とボム追加用アイテム（Ｂ）です。
　　
　アイテムを描画する処理は以下の通りです。
    if itemf=1 {
        gdx=itemx:gdy=itemy
        if ikind=0 {
            gdox=$C0:gdoy=$20
        }
        else {
            gdox=$E0:gdoy=$20
        }
        gdw=32:gdh=32
        gosub *Graphic_Draw
    }

　まとめますと、アイテムに関する処理は以下のようになります。

	; ゲームスタート時の初期設定
	noption=0

	; ステージスタート時の初期設定
	itemf=0

	; アイテムの移動
	if itemf=1 {
		itemy=itemy+2
		if itemy>=ysize { itemf=0 }
	}

	; アイテムの出現
	if (itemf=0)&((mappnt=1024)|(mappnt=2048)|(mappnt=3072)) {
		itemf=1
		if (mappnt=1024)|(mappnt=2048) { ikind=0 }
		if mappnt=3072 { ikind=1 }
		itemx=(xsize-32)/2
		itemy=-32
	}

	; 自機とアイテムの当たり判定
	if ((playerf=1)|(playerf=2))&(itemf=1)&(playerx<=(itemx+31))&((playerx+31)>=itemx)
		&(playery<=(itemy+31))&((playery+31)>=itemy) {
		itemf=0
		if ikind=0 {
			if noption<2 {
				noption=noption+1
			}
			else {
				score=score+500
				if score>hiscore { hiscore=score }
				if score>=oneup {
					nplayer=nplayer+1
					oneup=oneup+100000
				}
			}
		}
		else {
			nbomb=nbomb+1
		}
	}

	; アイテムを描画
	if itemf=1 {
		gdx=itemx:gdy=itemy
		if ikind=0 {
			gdox=$C0:gdoy=$20
		}
		else {
			gdox=$E0:gdoy=$20
		}
		gdw=32:gdh=32
		gosub *Graphic_Draw
	}