(1)自機の座標を増減する
　ここまでできれば、もう簡単です。あとはukey,dkey,lkey,rkeyの値に応じて、自機の座標(playerx,playery)を増減させればよいのです。ここでは、１度に４ドット動かすことにします。
  if ukey=1 { playery=playery-4 }
  if dkey=1 { playery=playery+4 }
  if lkey=1 { playerx=playerx-4 }
  if rkey=1 { playerx=playerx+4 }
　パソコンの画面は、ｙ座標は下がプラス方向、上がマイナス方向です。
　左と上が両方とも押されていたら、playery=playery-4とplayerx=playerx-4が行われ、左斜め上に動きます。たまたま上と下が同時に押された場合、playery=playery-4とplayery=playery+4が行われ、相殺されます。

(2)画面の端では動かさない
　画面の端に来たら、もうそれ以上動けないようにしなければなりません。例えば自機が左端にいる時（playerxが０の時）、playerx=playerx-4を行うとマイナスの値になってしまいますね。こういう場合は強制的にplayerxを０にします。
  if playerx<0 { playerx=0 }
  if playerx>608 { playerx=608 }
  if playery<0 { playery=0 }
  if playery>448 { playery=448 }
　画面のサイズが640×480ですから、右端のx座標は639、下端のy座標は479です。(playerx,playery)は自機の左上隅の座標で、自機のサイズが32×32ですから、右端にいる時playerxは608、下端にいる時playeryは448です。

(3)変更後の座標に自機の絵を描く
　あとは変更後の座標に自機を描くだけですが、ここで、アニメーションをさせたいと思います。アニメーションとは、キャラクタが動いている方向に傾いたり、くるくると回ったり、羽ばたいたりすることです。毎回同じ絵を描くのではなく、その都度違う絵を描くことです。
　自機が動いている方向によって、右に傾けたり左に傾けたりします。
　　
　samplecg.bmpに右に傾いた絵と左に傾いた絵を加えました。それぞれのサイズは32×32、左上隅の座標は(0,0)、(32,0)、(64,0)です。

　ddsetrectでコピー元の絵を指定する時に、右に動いている時には右に傾いた絵を、左に動いている時には左に傾いた絵を指定します。どちらでもない時は傾いていない絵を指定します。ここで、「右に動いている」とは右斜め上、右斜め下も含みます。
　右に動いていることを判別するにはどうすればいいでしょうか。rkeyが１の時ですね。本当にそれだけでしょうか？　たまたま右キーと左キーをいっしょに押してしまった場合、右に傾いた絵を描くのはおかしいですね。つまり、rkeyが１かつlkeyが０の時です。すると、自機を描く処理はこうなります。
  ddpos playerx,playery
  ddsetrect 0,0,32,32
  if (rkey=1)&(lkey=0) { ddsetrect 32,0,32,32 }
  if (lkey=1)&(rkey=0) { ddsetrect 64,0,32,32 }
  ddgcopy 1
　先にどちらにも傾いていない絵を指定し、右に動いていれば右に傾いた絵に指定し直しています。左も同様です。

　以上をふまえて、付加的な処理を加えた今回の部分は以下の通りです。

	digetjoynum
	njoy=stat	; つながっているジョイパッドの数

	ddsetrenewaltiming 60	; 画面の更新回数を６０回／秒にする。

	; メインループ
*Main_Loop
	await 0
	gosub *Clear_Screen

	; 自機の移動
	gosub *In_Key
	if ukey=1 { playery=playery-4 }
	if dkey=1 { playery=playery+4 }
	if lkey=1 { playerx=playerx-4 }
	if rkey=1 { playerx=playerx+4 }
	if playerx<0 { playerx=0 }
	if playerx>608 { playerx=608 }
	if playery<0 { playery=0 }
	if playery>448 { playery=448 }

	; 自機を描画
	ddpos playerx,playery
	ddsetrect 0,0,32,32
	if (rkey=1)&(lkey=0) { ddsetrect 32,0,32,32 }
	if (lkey=1)&(rkey=0) { ddsetrect 64,0,32,32 }
	ddgcopy 1
	ddredraw

	goto *Main_Loop

	; キー、ジョイパッドの入力
*In_Key
	ckey=0
	ukey=0
	dkey=0
	lkey=0
	rkey=0

	digetkeystate key,0
	if key&256!0 { ckey=1 }
	if key&1!0 { ukey=1 }
	if key&2!0 { dkey=1 }
	if key&4!0 { lkey=1 }
	if key&8!0 { rkey=1 }

	digetkeystate key,1
	if key&16777216!0 { ukey=1 }
	if key&2!0 { dkey=1 }
	if key&64!0 { lkey=1 }
	if key&1048576!0 { rkey=1 }

	if njoy>0 {
		digetjoystate key,0
		if key&16!0 { ckey=1 }
		if key&1!0 { ukey=1 }
		if key&2!0 { dkey=1 }
		if key&4!0 { lkey=1 }
		if key&8!0 { rkey=1 }
	}

	return

; メインループ
　自機の移動、描画は、このプログラムのメインとなるループです。このようなループを一般的にメインループと呼びます。

ddsetrenewaltiming 60
　ddsetrenewaltiming 60は、画面の更新がちょうど１秒間で６０回になるように時間調整を行います。
　　自機の移動→描画→ddredraw（画面の更新）
　これで１回のループとなります。このループの処理時間が1/60秒になるように待ち時間を入れるということです。
　　自機の移動→描画→待ち時間→ddredraw（画面の更新）
　　（待ち時間がddredrawの前に入るのか後に入るのかは分かりません。）
　パソコンの性能によって、プログラムの実行速度は変わります。ユーザによってゲームのスピードが違うことになります。この命令を行うことによって、どのパソコンでも１秒間で６０回の画面更新となります。（60fpsと表されます。）

await 0
　メインループにはawait 0を入れます。正直、理由は分かりません。０秒待つって、どういう事？　HMM . DLLのReadmeに、入れるように書いてあります。前に、長時間ループする処理にはawait 16を入れよと書きましたが、その代わりをしているのがddsetrenewaltiming 60とawait 0の組み合わせなのだろうと思います。（ちなみに、1/60秒は約16ミリ秒です。）

gosub *Clear_Screen
　毎回画面全体を消して描き直しています。このようなことをしても、現在のパソコンでは十分な速度が得られます。一昔前は考えられなかった事のようです。