自機の弾が敵に当たっているかどうかを判定します。

　弾が当たると敵はダメージを受け、ダメージが一定量になると爆発します。ダメージを受けたら、敵が白く光るようにします。爆発したらスコアを加算します。スコアがある値になるとワンアップ（自機が一機増える）します。

「プログラム起動時の初期設定」部分に以下の４点を加えます。
    hiscore=50000
    dim enelife,10
    dim dmgcnt,10
    dim eplcnt,10
　hiscoreはハイスコアです。プログラム起動時には５万点にすることにします。
　それぞれの敵はヒットポイントのようなものを持っていて、ダメージを受けるごとに減っていき、０になると爆発するものとします。「硬さ」という言い方をよくします。この耐久度が大きいほど、「硬い」と言います。硬さenelifeの配列変数宣言をここでやります。（eneはenemyの略です。）
　敵がダメージを受けている時の処理のために使うカウンタdmgcnt、敵が爆発中の処理のために使うカウンタeplcntの配列変数宣言もここでやります。（dmgはdamage、eplはexplosionの略です。）　

「ゲームスタート時の初期設定」処理を、「ステージスタート時の初期設定」処理の前に追加します。
　スコアを０点にします。
    score=0
　ワンアップは最初５万点で、以降１５万点、２５万点、……と、１０万点ごとに１機増えることにします。
    oneup=50000
　自機は最初３機あるものとします。
    nplayer=3
　（nはnumberの略です。）

　硬さenelifeの初期値はどこで入れたらいいかというと、敵が出現した時に設定するのが妥当ですから、「敵の出現」処理に追加します。
    ; 敵の出現
    if mappnt\64=0 {
        n=0
        w=-1
        repeat 10
            if enemyf.cnt=0 {
　　　　　　　　　・
　　　　　　　　　・
　　　　　　　　　・
                enelife.cnt=3
　　　　　　　　　・
　　　　　　　　　・
　　　　　　　　　・
            }
        loop
    }

　敵の絵と自機弾の絵とで重なっている部分があるかどうかを判別するのは、非常に難しいです。そこで、それぞれのキャラクタを四角形で近似します。四角形同士が重なっていれば、当たっていると判定します。
　　
　敵のサイズが３２×３２ドット、自機弾のサイズが４×１６ドットですから、当たり判定は以下のようになります。
    repeat 4
        if shotf.cnt=1 {
            x=shotx.cnt:y=shoty.cnt
            f=0
            repeat 10
                if ((enemyf.cnt=1)|(enemyf.cnt=2))&(x<(enemyx.cnt+32))&
                    ((x+4)>enemyx.cnt)&(y<(enemyy.cnt+32))&((y+16)>enemyy.cnt) {
                    f=1
                    敵に自機弾が当たった時の処理
                }
            loop
            if f=1 { shotf.cnt=0 }
        }
    loop
　４つの自機弾それぞれにつき、１０匹の敵と当たっているかどうかを判定します。変数fは、どれかの敵と当たったら１に、どれにも当たっていなかったら０になります。fが１の時、その弾を消去しています。
　図と２つめのif文が結びつかない人は、x<=(enemyx.cnt+31)とx<(enemyx.cnt+32)は同じである点に注意して下さい。
　敵がダメージを受けたら、少しの間白く光らせることにします。また爆発したら、爆発のアニメーションを表示し、それから消滅します。そこで、敵の存在フラグenemyfの意味を下記のように変更します。

• enemyf=0 : 消滅している。
• enemyf=1 : 存在している。（通常の状態。）
• enemyf=2 : ダメージを受け、白く光っている。
• enemyf=3 : 爆発中である。

　敵を"少しの間"光らせるのにも、爆発のアニメーションをやるのにもカウンタが必要となります。それぞれをdmgcnt、eplcntとします。敵がダメージを受けたらdmgcntに０を代入し、１ずつ増やしていき、ある値（ここでは３とします）になるまで敵を白く光らせます。３になったら、存在フラグをダメージを受けている状態から通常の状態に戻します。また敵が爆発したらeplcntに０を代入し、やはり１ずつ増やしていきます。この値によって、爆発の絵を変えていきます。ある値（ここでは１５とします）になったら、存在フラグを爆発中から消滅に変えます。
　　
「敵に自機弾が当たった時の処理」では、存在フラグenemyfを２にし、dmgcntに０を入れ、ヒットポイントenelifeを１減らします。
    enemyf.cnt=2
    dmgcnt.cnt=0
    enelife.cnt=enelife.cnt-1
　この時、enelifeが０になったら、enemyfを３にし、eplcntに０を入れます。また、scoreを２００点加算します。もしscoreがhiscoreを上回ったらhiscoreを更新します。scoreがoneup以上になったら残機数nplayerを１増やすとともにoneupに１０万を足します。
    if enelife.cnt=0 {
        enemyf.cnt=3
        eplcnt.cnt=0
        score=score+200
        if score>hiscore { hiscore=score }
        if score>=oneup {
            nplayer=nplayer+1
            oneup=oneup+100000
        }
    }

　まとめますと、「敵と自機弾の当たり判定を行う」処理は以下のようになります。
    repeat 4
        if shotf.cnt=1 {
            x=shotx.cnt:y=shoty.cnt
            f=0
            repeat 10
                if ((enemyf.cnt=1)|(enemyf.cnt=2))&(x<(enemyx.cnt+32))&
                    ((x+4)>enemyx.cnt)&(y<(enemyy.cnt+32))&((y+16)>enemyy.cnt) {
                    f=1
                    enemyf.cnt=2
                    dmgcnt.cnt=0
                    enelife.cnt=enelife.cnt-1
                    if enelife.cnt=0 {
                        enemyf.cnt=3
                        eplcnt.cnt=0
                        score=score+200
                        if score>hiscore { hiscore=score }
                        if score>=oneup {
                            nplayer=nplayer+1
                            oneup=oneup+100000
                        }
                    }
                }
            loop
            if f=1 { shotf.cnt=0 }
        }
    loop

[目次へ]｜[前へ]｜[次へ]