敵を出し、移動します。

　敵は最大１０個まで存在できることにします。自機の弾と同様、存在フラグ(enemyf)と座標(enemyx,enemyy)を配列変数として宣言します。あともう一つ、敵用のカウンター(enemycnt)を用意します。これは、敵のアニメーションと、敵の動きのために使います。
    dim enemyf,10
    dim enemyx,10
    dim enemyy,10
    dim enemycnt,10
　これは、「プログラム起動時の初期設定」に入れます。

「全体の流れ」の所でちょっと、一つ一つの種類について動きをプログラミングしていく場合と、移動パターンをデータ化してしまって、処理は一つですむようにする場合がある旨を書きました。ここでは、簡単にたくさんの敵の種類を作れる、後者の方にしようと思います。
　こんなふうに、左右にふらふらしながら降りてくる敵を作ります。
　　
　最初、左に８ドット、下に４ドット動かします。２回目は左に６ドット、下に４ドット動かします。３回目は左に４ドット、下に４ドットです。
　　
　何番目にｘ方向に何ドット、ｙ方向に何ドット動かすかを配列変数enemvdx(enemy move dxの略)、enemvdyに代入します。
    dim enemvdx,16
    dim enemvdy,16
    enemvdx.0=-8:enemvdy.0=4
    enemvdx.1=-6:enemvdy.1=4
    enemvdx.2=-4:enemvdy.2=4
    enemvdx.3=-2:enemvdy.3=4
    enemvdx.4=0:enemvdy.4=4
    enemvdx.5=2:enemvdy.5=4
    enemvdx.6=4:enemvdy.6=4
    enemvdx.7=6:enemvdy.7=4
    enemvdx.8=8:enemvdy.8=4
    enemvdx.9=6:enemvdy.9=4
    enemvdx.10=4:enemvdy.10=4
    enemvdx.11=2:enemvdy.11=4
    enemvdx.12=0:enemvdy.12=4
    enemvdx.13=-2:enemvdy.13=4
    enemvdx.14=-4:enemvdy.14=4
    enemvdx.15=-6:enemvdy.15=4
　これを順々に敵の座標に足しこんでいくと、ふらふらと動きます。１５までいったら、０に戻って繰り返します。 　これも、「プログラム起動時の初期設定」に入れます。

　「ステージスタート時の初期設定」で、存在フラグに０を代入します。
    repeat 10
        enemyf.cnt=0
    loop
　まだ背景のスクロール処理を作っていないのですが、敵はスクロールに合わせて出していきたいので、自機が今ステージのマップ上のどこにいるのかを表す変数mappnt(map pointの略)を追加します。最初が０で、１ドットスクロールすると１増えることにします。
    mappnt=0

　 　ここでは、６４ドットスクロールするたびに２匹ずつ敵を出します。すると、mappntが６４の倍数の時に出すことになります。ある数がある数の倍数であるかどうかを調べるのに、便利な演算子があります。
    if mappnt\64=0 {
        敵を出す処理
    }
　"\"はモジュロ演算子というもので、mappntを64で割った余りを求めます。余りが０であるということは、６４の倍数だということです。
　敵を出す処理ですが、自機から弾を出す処理と同様、要素０から順に存在フラグを見ていき、空いている（存在フラグが０である）要素に割り当てます。１度に２匹出すので、変数nに今何匹出したかを記憶させることにします。
    n=0
    repeat 10
        if enemyf.cnt=0 {
            敵を１匹出す処理
            n=n+1
            if n=2 { break }
        }
    loop
　空きが２箇所以上あれば２匹出しますし、１箇所しかなければ１匹だけ出しますし、１箇所もなければ１匹も出しません。
　敵を１匹出す処理は、座標を決め、存在フラグを１にし、敵用のカウンターを０にします。
　ｙ座標は０です。ｘ座標は、乱数で決めることにします。乱数というのは、「でたらめな値」です。サイコロをふると１から６までがでたらめに出ますが、それと同じです。
    rnd 値を入れる変数,上限の値
　これが、乱数を得る命令です。０から上限の値よりも１小さい数までのうちのどれかが変数に代入されます。
    randomize
　これは、乱数系列を変える命令です。乱数の出方を変えます。これがないと、プログラムを動かすたびに毎回同じ並びの乱数となります。サイコロを５回ふって、１，４，６，２，５という順に目が出たとすると、次にサイコロを５回ふると、また１，４，６，２，５の順に目が出てしまうということです。この命令はプログラムの最初に入れるといいですが、ここではステージスタート時に毎回乱数系列を変えることにします。
　敵が左右にふらふらしていることも考慮し、画面からはみ出さないよう、３２から５７６までの値のどれかをｘ座標にすることにします。ただし、２匹横に並べて出すので、下手をすると敵同士が重なってしまいます。敵の幅が３２ドットなので、ｘ座標には３２の倍数しか設定しないことにすると、部分的に重なったりしません。完全に重なる危険はありますが。
　　
    rnd r,18
    enemyx.cnt=(r+1)*32
　１行目で、０から１７のうちのどれかをでたらめに（ランダムに、という言い方をします）選んで、rに入れます。２行目で、１を足しますから１〜１８となり、３２倍しますから、３２から５７６までの３２の倍数となります。
　しかし、やはり完全に重なるのは嫌ですね。同じ乱数が２回続けて出たら、２匹のｘ座標は等しくなってしまいます。そこで、前に出た乱数を変数wに記憶させておいて、それとrの値が違えばそれでよしとし、同じだったら、違う値が出るまでrnd命令をやり直すことにします。
    repeat
        rnd r,18
        if r!w { break }
    loop
    w=r
　wには最初に−１を入れておきます。（１回目のrnd命令で、必ず違う値になるから。）
　repeatに引数を指定しないと、永久にループを繰り返します。（break文で抜け出します。）これは、
    *aaa
        rnd r,18
        if r=w { goto *aaa }
        w=r
　と同じですが、ラベルを追加するのが鬱陶しければ引数のないrepeat文を使うといいです。
　以上より、敵を出す処理は以下のようになります。
    if mappnt\64=0 {
        n=0
        w=-1
        repeat 10
            if enemyf.cnt=0 {
                repeat
                    rnd r,18
                    if r!w { break }
                loop
                w=r
                enemyx.cnt=(r+1)*32
                enemyy.cnt=0
                enemyf.cnt=1
                enemycnt.cnt=0
                n=n+1
                if n=2 { break }
            }
        loop
    }
　なお、"if r!w { break }"の方のbreak文は、あくまでも内側のrepeat〜loopから抜けるのであって、外側のrepeat〜loopからは抜け出しません。